Rumus Excel RANK, Mencari & Menentukan Ranking Peringkat Nilai di Excel

Rumus Excel RANK, Mencari & Menentukan Ranking Peringkat Nilai di Excel

Nadiem    Juni 11, 2020    Comment   

Rumus ranking excel. Cara membuat, menentukan serta mencari ranking atau peringkat nilai pada microsoft excel menggunakan fungsi Rank, Rank.AVG dan Rank.EQ.

Rumus ranking excel - Bagaimana cara merangking atau membuat ranking di excel? Microsoft Excel telah menyediakan fungsi RANK untuk mencari dan menentukan ranking atau peringkat sebuah nilai pada sekelompok daftar nilai angka.

Mulai versi Ms. excel 2010, microsoft excel mulai memperkenalkan fungsi RANK.AVG dan fungsi RANK.EQ sebagai alternatif pengganti fungsi RANK excel. Meskipun demikian kita masih bisa menggunakan fungsi RANK excel ini sampai versi terakhir saat ini.

Untuk itu jangan heran jika anda masih memakai Ms. Excel 2007 ke bawah maka Anda tidak akan menemukan fungsi RANK.EQ dan RANK.AVG.

Tutorial excel kami kali ini akan membahas ketiga fungsi excel tersebut.

Pada dasarnya ketiga fungsi excel (RANK, RANK.AVG dan RANK.EQ) ini digunakan untuk membuat ranking di excel atau mencari ranking serta peringkat nilai (angka) yang relatif terhadap sekelompok daftar nilai.

Jika anda memiliki sebuah daftar nilai misalnya, maka seolah-olah ketiga fungsi excel ini akan mengurutkan daftar nilai tersebut baik secara ascending maupun descending.

Untuk lebih memahami cara kerja perankingan atau pemeringkatan ketiga fungsi ini dalam rumus excel, silahkan membuat tabel data seperti berikut:

Apabila sudah anda lakukan, sekarang mari kita bahas ketiga fungsi ini satu persatu untuk membuat ranking serta menentukan rangking atau peringkat nilai pada excel.

1. Fungsi Excel Rank
2. Fungsi Excel Rank.EQ
3. Fungsi Excel Rank.AVG

Fungsi RANK Excel

Pada microsoft excel fungsi RANK adalah rumus yang digunakan untuk menentukan ranking atau membuat peringkat sebuah nilai pada sekelompok daftar nilai tertentu.

Sederhananya Fungsi RANK adalah fungsi excel untuk merangking sebuah nilai.

Cara Menggunakan Fungsi RANK

Penulisan rumus RANK mengikuti aturan sebagai berikut:

			RANK(Angka;Referensi;[order])
		

Keterangan :

• Angka : Merupakan nilai angka yang akan kita cari ranking atau peringkatnya.
• Referensi : Merupakan sekumpulan nilai angka dapat berbentuk array, referensi sel atau daftar angka sebagai acuan perankingan atau pemeringkatan.
• [order] : angka 0 atau 1 sebagai acuan pengurutan daftar nilai (Referensi) untuk menentukan ranking atua peringkat.

- Jika bernilai 0 atau dikosongkan maka daftar nilai seolah-olah akan diurutkan secara descending atau menurun.

- Jika bernilai 1 maka daftar nilai akan diurutkan secara ascending atau dalam urutan naik.

Contoh Fungsi RANK pada Rumus Excel

Pada contoh tabel di atas tuliskan rumus excel berikut pada cell D2:

			=RANK(C2;$C$2:$C$11;0)
		

Pada rumus excel tersebut nilai yang akan kita cari rankingnya adalah cell C2 (90) dengan refrensi daftar nilai $C$2:$C$11. Kenapa ada tanda $ pada rumus excel? ini bertujuan agar saat kita copykan ke bawah rumus tersebut, range data atau daftar nilai tersebut tidak berubah.

Setelah menuliskan rumus excel tersebut copy atau gunakan auto fill untuk sel-sel dibawahanya (D3 sampai D11).

Hasilnya akan seperti gambar di bawah ini:

Dari hasil penggunaan rumus Rank excel diatas kita peroleh peringkat nilai pertama adalah siswa dengan nomor urut 2, peringkat kedua adalah siswa dengan nomor urut 1 dan seterusnya.

Fungsi RANK.EQ Excel

Fungsi RANK.EQ akan menghasilkan rangking atau pemeringkatan nilai yang sama seperti yang dihasilkan oleh fungsi RANK. Karena memang pada dasarnya fungsi ini merupakan fungsi pengganti untuk fungsi RANK.

Cara Menggunakan Fungsi RANK.EQ :

Sintaksis penulisan fungsi Rank.EQ pada rumus excel adalah sebagai berikut:

			RANK.EQ(Number; Referensi; [order])
		

Keterangan :

Argument dari fungsi RANK.EQ sama dengan fungsi RANK sebelumnya.

• Number : Merupakan nilai angka yang akan kita cari ranking atau peringkatnya.
• Referensi : Merupakan referensi perangkingan yang berbetuk sekelompok nilai angka berupa array, referensi range atau daftar angka sebagai acuan perankingan atau pemeringkatan.
• [order] : Angka 0 atau 1 sebagai acuan pengurutan daftar nilai (Referensi) untuk menentukan ranking atua peringkat.

- Jika bernilai 0 atau dikosongka maka daftar nilai seolah-olah akan diurutkan secara descending atau menurun.

- Jika bernilai 1 maka daftar nilai akan diurutkan secara ascending atau dalam urutan naik.

Contoh Fungsi RANK.EQ pada Rumus Excel

Contoh kali ini masih menggunakan tabel data sebelumnya. Pada contoh tabel diatas tuliskan rumus excel berikut pada Cell D2:

			=RANK.EQ(C2;$C$2:$C$11;0)
		

Kemudian copy paste rumus excel tersebut untuk sel lain dibawahnya. Hasil dari pemeringkatan menggunakan fungsi RANK.EQ ini adalah sebagai berikut:

Dengan menggunakan order 0 maka nilai terbesar akan diberikan peringkat paling tinggi atau paling besar.

Jika anda menghendaki nilai terkecil mendapatkan ranking terbesar maka ubah argument order dengan angka 1.

Fungsi RANK.AVG Excel

Fungsi Excel RANK.AVG digunakan untuk menentukan ranking atau membuat peringkat nilai pada sekelompok daftar nilai dengan menambhakan rata-rata jumlah pemilik nilai tersebut.

Fungsi ini merupakan fungsi pengganti dari RANK yang diperkenalkan sejak versi Microsoft Office Excel 2010.

Dengan Fungsi ini jika ada nilai yang sama maka excel akan menghasilkan rata-rata ranking atau peringkat dari nilai yang memiliki ranking yang sama tersebut.

Hal ini berbeda dengan kedua fungsi sebelumnya. dimana jika ada nilai yang sama, maka semua nilai-nilai yang sama tersebut akan mendapatkan rangking yang sama pula sesuai urutannya.

Cara Menggunakan Fungsi RANK.AVG :

			RANK.AVG(Angka; Referensi; [order])
		

Keterangan :

Penjelasan masing-masing argument fungsi RANK.AVG ini sama dengan argument fungsi RANK.

• Angka : Nilai angka yang akan kita cari ranking atau peringkatnya.
• Referensi : Sekelompok nilai angka yang berupa array, referensi atau daftar angka sebagai acuan perankingan atau pemeringkatan.
• [order] : Angka 0 atau 1 sebagai acuan pengurutan daftar nilai (Referensi) untuk menentukan ranking atua peringkat. - Jika dikosongi atau bernilai 0 maka daftar nilai seolah-olah akan diurutkan secara descending atau menurun. - jika bernilai 1 maka daftar nilai akan diurutkan secara ascending atau dalam urutan naik.

Contoh Penggunaan Fungsi RANK.AVG pada Rumus Excel

Masih menggunakan tabel yang sama, pada contoh tabel diatas tuliskan rumus excel berikut pada sel D2:

			=RANK.AVG(C2;$C$2:$C$11;0)
		

Kemudian copy paste rumus tersebut untuk sel lain dibawahnya. Hasil dari pemeringkatan menggunakan fungsi RANK.AVG ini adalah sebagai berikut:

Jika anda perhatikan hasil dari fungsi Rank.AVG pada rumus excel diatas, maka nilai 70 mendapatkan rangking 7,5, sedangkan nilai 75 mendapatkan rangking 5,5.

Catatan :

1. Fungsi RANK dan fungsi RANK.EQ akan menghasilkan ranking yang sama untuk nilai duplikat.
2. Jumlah duplikat pada fungsi RANK dan RANK.EQ akan memepengaruhi ranking selanjutnya. Sehingga pada contoh diatas kita tidak menemukan ranking 6 dan 8.
3. Dengan Fungsi RANK.AVG, jika ada duplikat nilai maka RANK.AVG akan mengambil rata-rata dari nilai rangking duplikat tersebut.
4. Tanda dollar ($) pada rumus-rumus excel diatas bermaksud mengabsolutkan range data sehingga ketika dicopy ke sel lain, range tersebut tidak berubah.

Untuk lebih jelasnya perhatikan perbedaan pencarian ranking dengan tiga fungsi ini:

Setelah mempelajari ketiga fungsi diatas jika anda ingin mengurutkan nama sesuai urutan rangking, silahkan baca tutorial pada tautan berikut: Rumus Excel untuk Mengurutkan Nama Sesuai Ranking Secara Otomatis

Sebenarnya masih ada masalah dengan pencarian peringkat atau ranking nilai dengan fungsi RANK, RANK.AVG dan RANK.EQ ini.

Masalah tersebut adalah bagaimana menghindari ranking duplikat yang dihasilkan dari rumus pemeringkatan tersebut.

Sampai jumpa pada tutorial belajar excel yang lain. :D

Seri tutorial membuat ranking di Excel lainnya:

• Cara membuat ranking di excel
• Cara mencegah peringkat ganda pada excel
• Rumus ranking ganda tanpa loncat
• Cara membuat ranking dengan banyak kriteria di excel
• Cara mengurutkan nama sesuai ranking secara otomatis

>> Gabung Telegram Channel <<

Rumus Excel untuk Membuat Ranking dengan Banyak Kriteria pada Microsoft Excel

Rumus Excel untuk Membuat Ranking dengan Banyak Kriteria pada Microsoft Excel

Nadiem    Juni 11, 2020    Comment   

Rumus Excel tentang cara membuat ranking unik dengan banyak kriteria serta tidak terjadi ranking ganda, double atau duplikat ranking

Rumus Rangking Dengan Banyak Kriteria - Sebagaimana janji saya sebelumnya, kali ini saya akan menulis turorial belajar excel tentang cara ketiga mencegah duplikat ranking atau peringkat ganda. tutorial kali ini sekaligus membahas tentang cara membuat ranking Excel dengan multiple criteria atau ranking excel dengan banyak kriteria.

Contoh kasus menentukan ranking dengan banyak kriteria ini biasanya terjadi pada guru atau wali kelas lembaga pendidikan. Dimana dalam menetukan ranking siswa biasanya didasarkan pada jumlah nilai-nilai banyak mata pelajaran. Persoalan muncul tatkala jumlah nilai-nilai tersebut sama. Ketika terjadi jumlah nilai sama maka ranking didasarkan pada urutan nilai mata pelajaran tertentu.

File Latihan pembahasan rangking multi kriteria ini bisa anda download pada bagian akhir tutorial ini.

Perhatikan contoh gambar berikut ini:

Ranking Excel pada contoh diatas didasarkan pada jumlah nilai. Karena ada beberapa nilai yang sama maka muncul beberapa ranking ganda. Rumus excel pada cell H2 contoh tersebut adalah:

			=RANK.EQ(G2;$G$2:$G$11;0)
		

Copy-Pastekan rumus diatas ke cel-cel bawahnya jika anda mencoba berlatih sesuai gambar diatas.

Penentuan Ranking pada tutorial kali ini menggunakan Fungsi RANK.EQ. Jika anda menggunakan microsoft office 2007 atau kebawah gunakan Fungsi RANK. Kedua fungsi Excel ini menghasilkan nilai ranking yang sama.

Mulai Excel 2010 Microsoft Excel mulai memperkenalkan fungsi RANK.EQ dan RANK.AVG sebagai pengganti Fungsi RANK.

Jika pada kasus diatas anda hanya ingin membuat ranking yang unik atau tidak ganda berdasarkan jumlah nilai saja maka silahkan baca artikel belajar excel tentang Rumus Excel untuk Mencegah Duplicate Ranking yang sudah saya bahas sebelumnya.

Jika terjadi duplikat ranking seperti contoh diatas dan anda ingin menentukan ranking berdasarkan kriteria pada nilai-nilai yang diperoleh siswa, maka bacalah tutorial ini sampai selesai. :D

Pada kasus penetuan ranking excel ini misal kita ingin membuat kriteria bahwa ranking disusun berdasarkan "Jumlah Nilai". Jika "Jumlah Nilai" sama maka siswa atau nama yang memperoleh "Nilai 1" lebih tinggi maka akan mendapat ranking yang lebih sedikit. Jika "Jumlah Nilai" dan "Nilai 1" sama maka akan di prioritaskan untuk yang mendapat "Nilai 2" lebih tinggi begitu seterusnya dengan urutan kriteria "Nilai 3", "Nilai 4", dan "Nilai 5". Jika "Nilai 5" juga sama maka "Nama" yang mendapat "No" lebih kecil atau yang namanya ditulis lebih dahulu akan diprioritaskan.

Biasanya ranking disusun secara descending atau menurun. Dari nilai terbesar ke yang terkecil. Nilai terbesar mendapat ranking yang kecil. Misal ranking urutan 100,90,80 adalah 1,2,3.

Jadi urutan kriteria penentuan Ranking pada contoh ini adalah:

1. Jumlah Nilai
2. Nilai 1
3. Nilai 2
4. Nilai 3
5. Nilai 4
6. No

Untuk membuat Ranking Excel berdasarkan banyak kriteria kita membutuhkan Composite Key. Composite Key adalah kombinasi dari sel-sel kriteria sehingga membentuk sebuah key unik baru yang akan kita jadikan rujukan perankingan atau pemeringkatan.

Cara membuat Composit Key dalam kasus pemeringkatan multi kriteria kali ini adalah dengan membuat penjumlahan hasil perankingan pada masing-masing baris kolom kriteria yang sudah kita tetapkan. Agar lebih mudah difahami kita akan membuat kolom dummy atau kolom bantu.

Masing-masing pada cell J2, K2, L2, M2, N2, dan O2 tuliskan rumus excel berikut:

Pada sel J2 :

			=RANK.EQ(G2;$G$2:$G$11;1)*10^10
		

Pada sel K2 :

			=RANK.EQ(C2;$C$2:$C$11;1)*10^8
		

Pada sel L2:

			=RANK.EQ(D2;$D$2:$D$11;1)*10^6
		

Pada sel M2:

			=RANK.EQ(E2;$E$2:$E$11;1)*10^4
		

Pada sel N2:

			=RANK.EQ(F2;$F$2:$F$11;1)*10^2
		

Pada sel O2:

			=RANK.EQ(A2;$A$2:$A$11;0)
		

Rumus Excel pada masing-masing kolom tersebut bermaksud membuat ranking untuk masing-masing kriteria sesuai urutan kriteria yang sudah kita tetapkan diawal.

Untuk kolom J sampai N pemeringkatan atau perangkingan kita buat secara order ascending atau urutan naik. Agar jumlah atau nilai yang tinggi mendapat angka rangking yang tinggi pula.

Sedangkan pada kolom O atau sel O2 order pemeringkatan kita buat descending atau menurun. Tujuannya agar no yang lebih awal atau ada pada baris (row) atas mendapat Ranking yang lebih banyak secara angka sesuai kriteria yang kita tetapkan sebelumnya.

Adapun tujuan *10^10 (Kali 10 Pangkat 10), *10^8 (Kali sepuluh pangkat 8) dan seterusnya adalah agar hasil penjumlahan nanti bisa kita pakai sebagai composit key sebagai acuan pemeringkatan.

Rumus excel perkalian diatas tidak mutlak seperti itu. Angka dibelakang pangkat (^) tergantung/dipengaruhi dari jumlah siswa atau jumlah record yang akan kita ranking serta jumlah kriteria yang kita tetapkan.

Sebagai catatan juga bahwa dalam satu cell excel hanya menerima 15 digit angka. Maka jika composite key yang anda buat melebihi 15 digit pisahkan dulu menjadi dua atau tiga composite key dan buatlah composite key baru dari pecahan composite key tadi.

Intinya kita buat composite key yang bersifat unik (tidak ganda) berdasarkan kolom-kolom kriteria yang hasil akhirnya bisa kita Ranking lagi untuk mendapatkan ranking yang unik dan sesuai yang kita harapkan.

Jika rumus-rumus excel tadi sudah anda tuliskan berikutnya buat satu kolom lagi sebagai komposit key pada cel P2 dengan rumus excel:

			=J2+K2+L2+M2+N2+O2
		

Jika sudah copy pastekan semua rumus pada masing-masing cel tadi kebawah sehingga hasil akhirnya kita akan mendapatkan nilai seperti gambar berikut :

Langkah berikutnya buat sebuah kolom baru lagi pada kolom Q dan tuliskan rumus excel ini pada sel Q2:

			=RANK.EQ(P2;$P$2:$P$11;0)
		

Copy-pastekan rumus tersebut ke bawah sampai pada sel Q11 sehingga menjadi seperti ini:

Nah rumus pada kolom Q2 sampai Q11 ini merupakan ranking yang sudah memenuhi kriteria yang kita tetapkan di awal tadi.

Rumus Excel penyusunan Composit Key (Sel P2 Gambar dibawah) tadi jika kita gabung akan menjadi:

			=RANK.EQ(G2;$G$2:$G$11;1)*10^10 +RANK.EQ(C2;$C$2:$C$11;1)*10^8 +RANK.EQ(D2;$D$2:$D$11;1)*10^6 +RANK.EQ(E2;$E$2:$E$11;1)*10^4 +RANK.EQ(F2;$F$2:$F$11;1)*10^2 +RANK.EQ(A2;$A$2:$A$11;0)
		

Dan rumus Excel untuk membuat ranking dengan Banyak Kriteria (Sel H2 Gambar dibawah) menjadi:

			=RANK.EQ(P2;$P$2:$P$11;0)
		

Hasil Akhirnya akan seperti gambar dibawah ini:

Sebagai pelengkap silahkan download file contoh dibawah ini:

Dropbox

GDrive

*Jika link mati / tidak dapat diakses silahkan lapor via kontak yang tersedia

Jika masih belum bisa memahami silahkan dibaca lagi dari awal. Kalau berulangkali masih belum faham juga silahkan sampaikan dibagian komentar.

Seri tutorial membuat ranking di Excel lainnya:

• Cara membuat ranking di excel
• Cara mencegah peringkat ganda pada excel
• Rumus ranking ganda tanpa loncat
• Cara membuat ranking dengan banyak kriteria di excel
• Cara mengurutkan nama sesuai ranking secara otomatis

>> Gabung Telegram Channel <<

Rumus Excel untuk Mencegah Ranking atau Peringkat Ganda pada Microsoft Excel

Rumus Excel untuk Mencegah Ranking atau Peringkat Ganda pada Microsoft Excel

Nadiem    Juni 10, 2020    Comment   

Rumus excel untuk mencegah ranking ganda (duplikat ranking) atau untuk mencari dan menentukan peringkat nilai yang unik (tidak ganda) pada microsoft excel.

Seperti yang sudah saya singgung sebelumnya bahwa menentukan ranking dengan fungsi excel baik fungsi RANK, RANK.AVG, maupun RANK.EQ masih memiliki kekurangan. Kekurangan tersebut adalah adanya ranking atau peringkat ganda untuk nilai yang kembar atau nilai yang sama.

Tutorial belajar excel kali ini akan membahas mengenai cara mencegah ranking ganda tersebut.

Cara menghindarai duplikat rangking ini tentunya dengan menetapkan kriteria-kriteria tertentu yang anda kehendaki terlebih dahulu. Sebab kriteria ini akan menentukan model perankingan mana yang tepat untuk anda gunakan.

1. Menghindari Ranking Ganda Dengan Fungsi Countif
2. Mencegah Peringkat Ganda Dengan Fungsi IF & Countif
3. Membuat Ranking Tanpa Duplikat Berdasarkan Nilai-nilai Pada Cell lain

Jika anda memakai Microsoft Excel 2010 keatas, selain menggunakan fungsi RANK, anda bisa juga memakai fungsi RANK.EQ untuk menentukan rangking nilai excel. Kedua fungsi ini akan menghasilkan nilai ranking yang sama.

Sebelum berlanjut ke pembahasan tentang cara mencegah duplikat ranking excel, kita buat dulu contoh datanya seperti dibawah ini.

Data ini akan kita gunakan sebagai bahan latihan untuk rumus-rumus excel yang akan kita pakai pada tutorial excel kali ini.

Untuk data diatas kolam A sampai kolom E kita tulis secara manual. Sedangkan kolom Jumlah kita gunakan fungsi SUM utuk menjumlahkan Nilai 1, Nilai 2 dan Nilai 3 dengan rumus pada sel F2:

			=SUM(C2:E2)
		

Kemudian copy-paste ke sel lain dibawahnya. Kolom jumlah inilah yang akan kita jadikan acuan perangkingan nilai kita kali ini.

Adapun Kolom "RANKING" pada Cell G2 diatas menggunakan rumus excel :

			=RANK(F2;$F$2:$F$11)
		

Perhatikan penggunaan tanda $ pada rumus excel tersebut. Hal ini bertujuan untuk membuat referensi range tersebut absolut, sehingga tidak berubah saat kita copy-paste ke sel-sel lain dibawahnya.

Tentang tanda $ ini, untuk lebih jelasnya silahkan dibaca pada tautan berikut: Referensi Absolut ($) dan Relatif pada Microsoft Excel

Setelah selesai memasukkan data serta rumus-rumus excel diatas jika diperhatikan maka akan terlihat bahwa hasil pemeringkatan dengan menggunakan fungsi RANK exel diatas terdapat beberapa peringkat nilai yang ganda. Yakni pada peringkat atau rangking 1,3 dan 6.

Tutorial belajar excel kita kali ini akan membahas tentang pemecahan masalah duplikat rangking diatas.

Menghindari Ranking Ganda Dengan Fungsi COUNTIF Excel

Untuk mencegah rangking ganda atau membuat sebuah ranking atau peringkat yang unik sebenarnya relatif mudah salah satunya adalah menggunakan fungsi COUNTIF Excel.

Seperti yang terlihat pada gambar diatas dengan menggunakan fungsi RANK kita temukan ada beberapa ranking ganda pada hasil pemeringkatan. Ranking 1 ada 2. ranking 3 ada 3 dan ranking 6 ada 3.

Untuk membuat ranking yang unik dan tidak ganda gunakan rumus excel berikut pada Cell G2 kemudian copy-pastekan kebawah:

			=RANK(F2;$F$2:$F$11;0)+COUNTIF($F$2:F2;F2)-1
		

Sekali lagi perhatikan dan cermati penggunaan tanda $ pada rumus diatas.

Setelah anda copy-pastekan ke bawah hasil akhir pemeringkatan nilai diatas akan seperti ini :

Selain menggunakan rumus excel diatas anda bisa juga menggunakan rumus seperti ini dengan hasil yang sama:

			=RANK(F2;$F$2:$F$11;0)+COUNTIF($F$1:F1;F2)
		

Dengan menggunakan kedua rumus excel diatas maka tidak ada lagi duplikat ranking. Hanya saja nilai yang ada di baris yang lebih awal akan mendapatkan rangking yang lebih kecil. Sehingga terkesan bahwa siswa no.4 mendapatkan jumlah nilai yang lebih baik daripada siswa nomor 7 padhal sebenarnya jumlah nilainya sama.

Sebagai alternatif lain gunakan model perangkingan selanjutnya.

Mencegah Ranking Ganda Dengan Fungsi IF Dan COUNTIF Excel

Ada kalanya kita tetap ingin memberikan peringkat yang sama namun dengan keterangan urutan jika ada ranking yang ganda atau kembar.

Misal dalam kasus nilai siswa, kita ingin siswa yang memiliki nilai yang sama mendapat peringkat yang sama namun dengan keterangan tambahan 1,2,3, dst. untuk ranking duplikatnya, sehingga tidak ada kesan bahwa anak yang satu lebih unggul dibandingkan dengan anak yang lainnya.

Untuk kriteria pemeringkatan semacam ini gunakan rumus excel berikut untuk perankingannya:

			=IF(COUNTIF($F$2:$F$11;F2)>1; RANK(F2;$F$2:$F$11;0)&" ("&COUNTIF($F$2:F2;F2)&")"; RANK(F2;$F$2:$F$11;0))
		

Hasil dari rumus excel tersebut adalah:

Cara kerja rumus excel diatas adalah dengan melakukan pengecekan dulu dengan fungsi IF Excel apakah ada nilai ganda atau tidak:

			COUNTIF($F$2:$F$11;F2)>1
		

Jika terdapat duplikat nilai maka excel menjalankan rumus :

			RANK(F2;$F$2:$F$11;0)&" ("&COUNTIF($F$2:F2;F2)&")"
		

Jika tidak ada duplikat Excel akan menjalankan rumus:

			RANK(F2;$F$2:$F$11;0)
		

Selain menggunakan keterangan urutan rangking seperti hasil diatas, anda bisa juga menambahkan keterangan jumlah duplikat seperti gambar berikut:

Namun dengan cara ini nilai ranking tidak akan unik, sehingga tidak sesuai dengan pembahasan kita kali ini. Namun demikian, jika seperti gambar diatas yang anda inginkan, maka anda bisa mengggunakan rumus excel seperti berikut:

			=IF(COUNTIF($F$2:$F$11;F2)>1; RANK(F2;$F$2:$F$11;0)&" ("&COUNTIF($F$2:$F$11;F2)&")"; RANK(F2;$F$2:$F$11;0))
		

Membuat Ranking Yang Unik(Tidak Ganda) Berdasarkan Nilai Cell Pada Kolom Lain

Cara ketiga ini adalah menentukan ranking yang ganda berdasarkan nilai-nilai pada kolom lain.

Maksudnya, jika ada jumlah nilai yang sama maka perankingan akan dilakukan berdasarkan skala prioritas pada masing-masing nilai yang dijumlahkan.

Misal pada contoh kasus diatas ini, jika ada nilai ranking yang ganda maka "NAMA" yang mendapatkan "NILAI 1" lebih tinggi akan mendapat ranking yang lebih unggul. Jika "NIALI 1" juga sama maka akan diprioritaskan "NAMA" yang mendapatkan "NILAI 2" lebih tinggi. Jika "NILAI 1" dan "NILAI 2" juga sama maka akan diprioritaskan yang mendapat "NILAI 3" lebih tinggi.

Untuk cara ketiga ini akan saya bahas tersendiri pada artikel belajar excel berikutnya : Rumus Excel untuk Membuat Ranking dengan Banyak Kriteria pada Microsoft Excel.

Sebagai bahan latihan saya sertakan file excel untuk tutorial kali ini, silahkan download melalaui link di bawah ini :

Dropbox

GDrive

*Jika link mati / tidak dapat diakses silahkan lapor via kontak yang tersedia

Semoga rumus-rumus diatas dapat membantu memecahkan permasalah perangkingan anda.

Jika anda memiliki kriteria tertentu terkait cara menghindari duplikat ranking ini silahkan sampaikan dikolom komentar yang telah tersedia. Kami akan sangat senang membantu sebisa mungkin untuk mencari solusi atas masalah excel anda.

Seri tutorial membuat ranking di Excel lainnya:

• Cara membuat ranking di excel
• Cara mencegah peringkat ganda pada excel
• Rumus ranking ganda tanpa loncat
• Cara membuat ranking dengan banyak kriteria di excel
• Cara mengurutkan nama sesuai ranking secara otomatis

>> Gabung Telegram Channel <<

Fungsi/Rumus COUNTIFS, Cara Menghitung Banyak Data Yang Memenuhi Banyak Kriteria Pada Excel

Fungsi/Rumus COUNTIFS, Cara Menghitung Banyak Data Yang Memenuhi Banyak Kriteria Pada Excel

Nadiem    Juni 10, 2020    Comment   

Rumus COUNTIFS: Cara menghitung jumlah data atau banyak data pada cell yang memenuhi banyak kriteria, syarat atau kondisi tertentu dengan menggunakan fungsi Countifs Excel

Rumus COUNTIFS Excel - Sebelumnya kita sudah belajar tentang fungsi COUNT dan fungsi COUNTIF excel. Pada halaman ini Kelas Excel akan membahas tentang bagaimana cara menggunakan fungsi rumus COUNTIFS pada Excel untuk menghitung banyak data atau sel yang memenuhi banyak kriteria.

• Pengertian Fungsi COUNTIFS Excel
• Cara Mengguakan Fungsi COUNTIFS Excel
• Contoh Rumus COUNTIFS di Excel

Jika menghendaki menghitung sel yang mengandung teks tertentu silahkan menuju halaman berikut: Rumus Menghitung Jumlah Data Yang Berisi Teks Tertentu

Pengertian FUngsi COUNTIFS Excel

Pada rumus excel, fungsi COUNTIFS digunakan untuk mengetahui jumlah data atau sel yang memenuhi banyak kriteria.

Menghitung jumlah cell yang dimaksud disini berbeda dengan menjumlah menggunakan fungsi SUM atau variannya. Maksud menjumlah disini adalah mencacah atau menghitung banyak cell yang memiliki nilai atau isi sesuai dengan kriteria tertentu. Dengan kata lain menghitung banyaknya pemilik data.

Misalnya menghitung jumlah cell yang berisi angka diatas 100, menghitung jumlah cell yang berisi teks tertentu dan lain sebagainya.

Jika anda bermaksud menghitung jumlah cell yang berisi bilangan numeric atau angka maka gunakan fungsi COUNT yang sudah kami bahas sebelumnya.

Untuk menghitung jumlah cell yang hanya memenuhi satu kriteria maka gunakan fungsi COUNTIF.

Adapun cara menghitung jumlah sel yang memenuhi banyak syarat atau multi kriteria adalah dengan menggunakan fungsi COUNTIFS.

Rumus excel COUNTIFS ini sebenarnya mirip dengan rumus COUNTIF Excel yakni sama-sama menghitung jumlah cell pada sebuah rentang data (Data Range) yang memenuhi kriteria tertentu. Perbedaanya terletak pada jumlah kriteria atau syarat cell yang akan dihitung atau dicacah.

Jika Fungsi COUNTIF hanya menghitung Cell dengan syarat tunggal, fungsi COUNTIFS dapat menghitung jumlah atau banyaknya cell yang memenuhi lebih dari satu syarat atau kriteria.

Cara Menggunakan Fungsi COUNTIFS Excel

Cara menggunakan fungsi countifs dalam rumus excel adalah sebagai berikut:

			COUNTIFS(criteria_range1; criteria1; [criteria_range2; criteria2]…)
		

Keterangan:

criteria_range1

Sebuah rentang sel yang akan dievaluasi berdasarkan syarat tertentu (criteria1)

criteria1

Kriteria yang akan diterapkan pada rentang sel pertama (criteria_range1)

criteria_range2

Sebuah rentang sel kedua yang akan dievaluasi berdasarkan syarat tertentu (criteria2)

criteria2

Kriteria yang akan diterapkan pada rentang sel pertama (criteria_range2)

Kriteria yang akan diterapkan pada fungsi ini dapat berupa angka, ekspresi, referensi sel, atau teks yang akan menentukan cell mana saja yang akan dihitung atau dicacah.

Contoh Rumus COUNTIFS Excel

Perhatikan tabel data berikut :

Dari tabel diatas tuliskan rumus excel berikut pada cell A9:

			=COUNTIFS(C2:C6;80;D2:D6;70)
		

Rumus excel diatas bernaksud menghitung jumlah data siswa yang memiliki nilai 80 pada kolom Nilai A dan memiliki nilai 70 pada kolom Nilai B. Jumlah siswa yang memenuhi kriteria tersebut ada dua yakni nomor 1 dan 3.

Selanjutnya tuliskan rumus excel berikut pada cell A10 :

			
				=COUNTIFS(C2:C6;">70";D2:D6;">70")
		

Rumus excel ini menghitung jumlah siswa yang mendapatkan nilai lebih dari 70 untuk Nilai A dan lebih dari 70 juga untuk Nilai B. Siswa yang memenuhi kriteria tersebut adalah siswa nomor 1 dan nomor 5 jadil hasil rumus excel ini adalah 2.

Untuk kriteria berupa teks Anda bisa menambahkan karakter Tanda tanya (?) maupun bintang (*) seperti pada penggunaan fungsi-fungsi lainnya. Tanda tanya(?) mewakili 1 karakter teks sedangkan tanda bintang (*) mewakili banyak karakter teks.

Tanda tanya atau bintang ini biasa disebut sebagai karakter wilcard. Untuk contohnya mirip seperti yang sudah saya contohnya pada pembahasan rumus countif sebelumnya.

Untuk contoh-contoh penggunaan lainnya silahkan bereksperimen :D. Jika menemui kendala sampaikan di kolom komentar.

Khusus untuk menghitung cell yang kosong atau tidak kosong Anda bisa menggunakan fungsi COUNTA atau COUNTBLANK.

Selamat Belajar.

>> Gabung Telegram Channel <<

Fungsi LARGE dan SMALL, Rumus Mencari Nilai Terbesar dan Terkecil Ke-n di Excel

Fungsi LARGE dan SMALL, Rumus Mencari Nilai Terbesar dan Terkecil Ke-n di Excel

Nadiem    Juni 09, 2020    Comment   

Fungsi LARGE dan SMALL, contoh dan cara menggunakan rumus Large dan Small di excel untuk mencari nilai terbesar dan terkecil ke-2, ke-3 dan ke-n dalam urutan data.

Rumus LARGE dan SMALL Excel - Sebelumnya kita sudah membahas tentang cara mencari nilai tertinggi dan terendah dengan fungsi MAX dan MIN. Kedua fungsi Excel tersebut hanya mendapatkan nilai tertinggi dan terendah saja.

Lalu bagaimana jika kita menghendaki untuk mencari nilai tertinggi ke-2 atau nilai terendah ke-5 dari sekumpulan bilangan atau data?

Atau Anda sedang membutuhkan rumus excel yang bisa digunakan untuk mencari 3 nilai tertinggi atau 3 nilai terendah misalnya.

Untuk memenuhi kebutuhan semacam ini Microsoft Excel sudah menyediakan dua fungsi lain, yakni fungsi SMALL dan fungsi LARGE.

Fungsi/Rumus Excel	Keterangan
LARGE	Fungsi/Rumus untuk mencari nilai terbesar ke-?
SMALL	Fungsi/Rumus untuk mencari nilai terkecil ke-?

Berikut panduan lebih lengkap cara menggunakan kedua fungsi excel tersebut.

• Pengertian Fungsi SMALL dan LARGE di Excel
• Cara Menggunakan fungsi SMALL dan LARGE
• Contoh Rumus SMALL dan LARGE di Excel
• Hal-hal Yang Perlu Diperhatikan Saat Menggunakan Rumus SMALL dan LARGE Pada Excel

Pengertian Fungsi SMALL dan LARGE Excel

Fungsi SMALL adalah salah satu fungsi excel yang digunakan untuk mendapatkan nilai terkecil ke-sekian. Sedangkan fungsi LARGE digunakan untuk mendapatkan nilai terbesar ke-sekian.

Kedua fungsi SMALL dan LARGE ini sebenarnya mirip dengan fungsi MIN dan MAX, yakni sama-sama digunakan untuk mencari nilai terendah/terkecil dan nilai tertinggi/terbesar pada sekumpulan data atau bilangan nilai.

Hanya saja fungsi SMALL dan LARGE mempunyai kelebihan selain untuk dapat menemukan nilai paling rendah atau paling tinggi juga bisa digunakan untuk mencari nilai terkecil ke-n dan terbesar ke-n yang relatif pada urutan sekumpulan data. Sehingga bisa dibilang kedua fungsi ini lebih produktif ketimbang fungsi MIN dan MAX pada Microsoft Excel.

Cara Menggunakan Fungsi SMALL dan LARGE Pada Excel

Cara menggunakan Fungsi SMALL mengikuti sintaksis

			SMALL(array; k)
		

Sedangkan cara menggunakan fungsi LARGE adalah dengan cara penulisan berikut:

			LARGE(array; k)
		

Keterangan:

• Array : Merupakan kumpulan bilangan atau rentang data yang ingin kita tentukan nilai terkecil atau terbesar ke-sekiannnya.
• K : Merupakan posisi urutan dalam array atau rentang data yang ingin kita dapatkan.

Contoh Rumus SMALL Dan LARGE di Excel

Acuan data untuk contoh-contoh dibawah ini adalah data penjualan berikut :

Dari data tersebut rumus excel untuk mencari Data penjualan X terbesar ke-3 adalah :

			=LARGE(B2:B7;3)
		

Sedangkan rumus excel untuk mencari nilai penjualan X terkecil ke-3 adalah

			=SMALL(B2:B7;3)
		

Untuk mendapatkan nilai penjualan Y terbesar ke-3 menggunakan rumus excel:

			=LARGE(C2:C7;3)
		

Adapun untuk nilai terendah ke-3 penjualan Y adalah dengan rumus excel:

			=SMALL(C2:C7;3)
		

Rumus Excel untuk mencari nilai penjualan X dan Y terbesar ke-2 adalah:

			=LARGE(B2:C7;2)
		

Sedangkan nilai terendah ke-2 untuk penjualan X dan Y adalah:

			=SMALL(B2:C7;2)
		

1. Untuk mencari nilai terbesar pertama (ke-1) selain menggunakan fungsi LARGE anda juga bisa menggunakan fungsi MAX.
2. Untuk mencari nilai terkecil pertama (ke-1) selain menggunakan fungsi SMALL anda juga bisa menggunakan fingsi MIN.
3. Menggunakan fungsi MAX untuk LARGE ke-1 dan MIN untuk SMALL ke-1 akan menghasilkan nilai yang sama.

Hal-hal Yang Perlu Diperhatikan Saat Menggunakan Fungsi SMALL Dan LARGE Pada Microsoft Excel

Saat menggunakan rumus large atau rumus Small di excel ada beberapa hal yang perlu Anda perhatikan. Antara lain:

• Jika array atau range data kosong, maka Fungsi SMALL dan LARGE akan menghasilkan nilai kesalahan #NUM!
• Jika k ≤ 0 (bernilai minus) atau jika k melebihi jumlah data, Fungsi SMALL akan menghasilkan nilai kesalahan #NUM!

Jika sebelum ini kita membahas tentang cara mencari Ranking dengan excel maka fungsi SMALL dan LARGE ini bisa kita manfaatkan untuk mengurutkan data-data hasil perangkingan yang telah kita lakukan sebelumnya. Tentang hal ini akan saya bahas pada artikel belajar Excel berikutnya.

>> Gabung Telegram Channel <<

Rumus COUNTA & COUNTBLANK, Cara Mengetahui Jumlah Sel Kosong dan Sel Yang Terisi di Excel

Rumus COUNTA & COUNTBLANK, Cara Mengetahui Jumlah Sel Kosong dan Sel Yang Terisi di Excel

Nadiem    Juni 08, 2020    Comment   

Rumus COUNTA-COUNTBLANK, Cara menghitung jumlah sel kosong dan sel yang terisi teks maupun angka menggunakan fungsi counta dan countblank pada microsoft excel

Rumus COUNTA dan COUNTBLANK Excel - Pada artikel sebelumnya kita sudah membahas tentang cara menghitung sel excel yang berisi bilangan angka, yakni dengan menggunakan fungsi COUNT. Sehingga jika sebuah sel ada yang berisi teks maka sel tersebut tidak akan masuk hitungan.

Jika kita bermaksud menghitung jumlah sel yang berisikan teks maka excel menyediakan sebuah fungsi yang bisa kita manfaatkan untuk menghitung jumlah sel-sel tersebut. Fungsi Excel yang saya maksud adalah fungsi COUNTA.

Lalu bagaimana jika kita hendak menghitung jumlah sel kosong? Untuk keperluan itu excel menyediakan fungsi COUNTBLANK.

Fungsi/Rumus Excel	Keterangan
COUNTA	Fungsi/Rumus excel untuk menghasilkan jumlah sel yang tidak kosong (empty)
COUNTBLANK	Fungsi/Rumus excel untuk menghasilkan jumlah sel yang kosong (empty)

Sekilas fungsi ini tidak akan ada gunanya. Namun jangan salah, fungsi ini akan sangat kita butuhkan dalam kasus-kasus excel tertentu.

Untuk saat ini akan saya jelaskan dulu bagaimana cara kerja kedua fungsi ini.

• Fungsi COUNTA Excel

• Cara Menggunakan Fungsi Counta
• Contoh Rumus Counta

Fungsi COUNTBLANK Excel

• Cara Menggunakan Fungsi Countblank
• Contoh Rumus Countblank

Fungsi COUNTA Excel, Rumus Excel Untuk Menghitung Jumlah Cell Yang Tidak Kosong

Fungsi Rumus COUNTA pada Excel digunakan untuk menghitung jumlah sel yang tidak kosong (empty) pada rentang sel tertentu.

Dengan rumus COUNTA kita tidak hanya menghitung sel yang berisi angka saja, sel yg berisi teks juga akan ikut terhitung.

Jika hanya menghendaki menghitung sel yang berisi teks tertentu maka gunakan fungsi COUNTIF atau menggunakan fungsi COUNTIFS jika kriterianya lebih dari satu (banyak).

Cara Menggunakan Fungsi Counta

Cara menggunakan fungsi atau rumus Counta Excel adalah seagai berikut:

			COUNTA(value1; [value2]; ...)
		

Argument value1, value2 pada fungsi ini adalah rentang data yang akan kita hitung jumlah sel yang ada isinya. Pada fungsi COUNTA ini, kita bisa memasukkan beberapa range excel sekaligus.

Contoh Rumus Counta

Contoh penggunaan rumus COUNTA di excel bisa Anda lihat pada contoh berikut:

Pada Cell F2 rumus excel yang digunakan adalah:

			=COUNTA(A2:C4)
		

Rumus counta ini digunakan untuk menghitung cell yang terisi pada range A2:A4. Hasil dari rumus tersebut adalah 8.

Untuk cell F3 rumus counta digunakan untuk menghitung jumlah cell yang terisi pada range A7:A10. Rumus excelnya sebagai berikut:

			=COUNTA(A7:C10)
		

Hasil rumus diatas adalah 10.

Untuk Cell F4, Rumus COUNTA digunakan untuk menghitung cell yang terisi pada range A2:C4 dan Range A7:C10.

			=COUNTA(A2:C4;A7:C10)
		

Hasil rumus diatas adalah 18

Anda butuh sedikit hati-hati dalam menggunakan fungsi ini. Karena COUNTA juga akan menghitung setiap tipe informasi, termasuk nilai kesalahan dan empty teks atau teks kosong ("") yang dihasilkan oleh sebuah rumus excel. Fungsi COUNTA ini juga akan cell yang berisi spasi saja.

Fungsi COUNTBLANK Excel, Rumus Excel Untuk Menghitung Jumlah Cell Kosong

Rumus COUNTBLANK Excel ini bisa dibilang kebalikan dari rumus COUNTA.

Fungsi COUNTBLANK di Excel digunakan untuk mengetahui atau menghitung jumlah sel kosong(empty) pada rentang sel tertentu yang kita tentukan.

Bagaimana cara menggunakannya? kita lanjutkan pada pembahasan berikutnya di bawah ini.

Cara Menggunakan Fungsi Countblank

Cara menggunakan fungsi rumus COUNTBLANK cukup mudah. Yakni dengan mengikuti kaidah peulisan berikut:

			COUNTBLANK(range)
		

Argument range pada fungsi COUNTBLANK ini merupakan kumpulan sel yang akan kita hitung jumlah sel kosongnya.

Contoh Rumus Countblank

Contoh penggunaan rumus Countblank pada microsoft excel adalah sebagai berikut:

Dari contoh diatas jika memasukkan Rumus Excel berikut pada cell E3 akan menghasilkan nilai 2 :

			=COUNTBLANK(A2:A11)
		

yakni menghitung jumlah sel A6 dan sel A9 yang kosong. Sekarang coba masukkan rumus berikut pada cell E4:

			=COUNTBLANK(A2:B11)
		

Rumus diatas akan meghasilkan nilai 5 yakni jumlah sel kosong pada A6, A9, B4, B7, dan B10.

Sebagai catatan, bahwa saat menggunakan rumus COUNTBLANK, nilai empty teks("") sebagai nilai kosong juga.

Panduan lebih lanjut tentang menghitung sel yang mengandung teks tertentu bisa anda pelajari pada halaman berikut: Rumus Menghitung Jumlah Data Yang Terisi Teks Tertentu Pada Microsoft Excel

Masih belum jelas? silahkan sampaikan dikolom komentar.

>> Gabung Telegram Channel <<

Rumus AVERAGEIF, Menghitung Rata-rata Dengan Kriteria Tertentu Pada Microsoft Excel

Rumus AVERAGEIF, Menghitung Rata-rata Dengan Kriteria Tertentu Pada Microsoft Excel

Nadiem    Juni 01, 2020    Comment   

Rumus AVERAGEIF, Cara menggunakan fungsi Averageif untuk menghitung rata-rata nilai dengan seuah kondisi, syarat atau kriteria tertentu pada microsoft excel.

Bagaimanakah cara menghitung rata-rata nilai dengan sebuah kriteria tertentu?

Untuk menghitung nilai rata-rata di excel Anda bisa menggunakan Fungsi AVERAGE Pada microsoft Excel. Namun, dengan fungsi AVERAGE rata-rata yang dihitung adalah dari seluruh nilai yang diberikan.

Pada kasus-kasus tertentu kita butuh menghitung nilai rata-rata dengan syarat atau kriteria tertentu.

Misalnya Anda ingin menghitung nilai rata-rata nilai dari kelompok laki-laki saja atau perempuan saja. Contoh lain Anda inginmenghitung nilai rata-rata pada sebuah range data tanpa melibatkan sel kosong atau sel yang bernilai nol (0).

Untuk kebutuhan semacam ini microsoft excel menyediakan fungsi AVERAGEIF.

Fungsi AVERAGEIF adalah salah satu fungsi statistik pada excel yang digunakan untuk menghitung nilai rata-rata dengan sebuah kriteria atau syarat tertentu.

Bagaimana cara menggunakan rumus AVERAGEIF ini? mari kita pelajari bersama.

• Cara Menggunakan Fungsi AVERAGEIF Excel
• Contoh Rumus AVERAGEIF Excel
• Catatan Dalam Menggunakan Rumus AVERAGEIF

Cara Menggunakan Fungsi AVERAGEIF Excel

Cara menggunakan rumus Averageif excel adalah sebagai berikut:

			AVERAGEIF(Range; Criteria; [Average_range])
		

Keterangan:

Range

Merupakan range data yang akan kita cocokkan dengan kriteria. Dapat berupa sel, range , sekumpulan angka, named range, array maupun referensi sel.

Criteria

Merupakan kondisi/syarat/kriteria yang akan menentukan sel/ nilai mana saja yang akan kita jadikan dasar menghitung rata-rata. Bisa berupa angka, ekspresi logika, teks maupun referensi sel.

Average_range

Argumen ini bersifat opsional (bisa diisi atau tidak), yakni Range data yang akan dihitung rata-ratanya. Jika dikosongkan atau tidak diisi maka yang akan digunakan adalah argumen Range.

Contoh Rumus AVERAGEIF Excel

Berikut contoh penggunaan rumus Averageif pada office excel

Keterangan:

Pada contoh 1 kita menghitung Rata-rata penjualan "Toko 1" rumus excel yang digunakan:

			=AVERAGEIF(B2:B9;"Toko 1";D2:D9)
		

Pada contoh 2 kita menghitung rata-rata penjualan "Barang 2". Rumus excel yang digunakan:

			=AVERAGEIF(C2:C9;"Barang 2";D2:D9)
		

Pada contoh 3 kita menghitung rata-rata penjualan barang diatas 10. Rumus excel yang digunakan:

			=AVERAGEIF(D2:D9;">10")
		

Pada contoh 3 di atas hanya penjualan yang lebih dari 10 saja yang dihitung rata-ratanya. Argument Average_range pada rumus excel nomor 3 dikosongkan sehingga rata-rata dihitung berdasarkan argument Range "D2:D9".

Catatan Dalam Menggunakan Fungsi AVERAGEIF Excel

Saat menggunakan rumus Averageif pada sebuah rumus excel, ada beberapa hal yang perlu anda perhatikan:

1. Kriteria dalam bentuk expresi logika dan teks harus dimasukkan atau diapait oleh double quote("). misal: "Toko 1", ">10". Ekspresi logika yang bisa digunakan bisa anda pelajari pada bahasan tentang operator perhitungan rumus exel.
2. Kita dapat menggunakan karakter wildcard, tanda tanya (?) dan tanda bintang (*), dalam kriteria. Tanda tanya mewakili karakter tunggal apa pun, sedangkan tanda bintang mewakili banyak karakter.
3. Kondisi, syarat atau kriteria pada fungsi AVERGEIF hanya 1 jenis. Gunakan AVERAGEIFS untuk menghitung rata-rata nilai berdasarkan banyak kriteria.

Demikian tutorial cara menghitung rata-rata berkriteria pada excel menggunakan rumus Averageif. Semoga bermanfaat.

Beberapa tutorial mengenai rumus rata-rata excel:

• Rumus Average: Rumus menghitung rata-rata di excel
• Rumus Averageif: Cara Menghitung rata-rata dengan sebuah kriteria
• Rumus Averageifs: Cara Menentukan rata-rata dengan banyak kriteria
• Rumus Menghitung rata-rata tanpa mengikutkan angka 0 (Nol) & sel kosong di excel

>> Gabung Telegram Channel <<

Rumus AVERAGEIFS, Cara Menghitung Rata-rata Nilai Dengan Banyak Kriteria Di Excel

Rumus AVERAGEIFS, Cara Menghitung Rata-rata Nilai Dengan Banyak Kriteria Di Excel

Nadiem    Juni 01, 2020    Comment   

Fungsi/Rumus AVERAGEIFS, rumus excel untuk menghitung rata-rata nilai yang memenuhi banyak kriteria, kondisi, atau syarat tertentu pada microsoft excel.

Pada microsoft excel, fungsi AVERAGEIFS adalah rumus excel yang digunakan untuk menghitung rata-rata nilai sekumpulan data yang memenuhi beberapa kriteria.

Dengan rumus AVERAGEIFS Anda bisa menghitung atau mencari rata-rata dengan banyak syarat atau kondisi tertentu.

Fungsi ini sedikit berbeda dengan fungsi AVERAGEIF yang hanya menghitung rata-rata dengan kriteria tunggal.

Dengan fungsi AVERAGEIFS kita bisa menetapkan sampai 127 kriteria atau kondisi untuk menghitung rata-rata sekumpulan data.

Sedangkan untuk menghitung rata-rata tanpa kriteria, syarat maupun kondisi tertentu anda bisa menggunakan fungsi AVERAGE yang sudah dijelaskan pada bagian lain.

Lalu bagaimana cara menggunakan fungsi AVERAGEIFS excel ini?

Pada bahasan kali ini kita akan belajar tentang cara menggunakan fungsi AVERAGEIFS untuk menghitung nilai rata-rata berdasarkan beberapa syarat, kriteria atau kondisi tertentu sesuai yang kita inginkan.

• Cara Menggunakan Fungsi AVERAGEIFS Excel
• Contoh Rumus AVERAGEIFS Excel
• Catatan Dalam Menggunakan Rumus AVERAGEIFS

Cara Menggunakan Fungsi AVERAGEIFS Excel

Pada rumus excel cara menggunakan fungsi AVERAGEIFS adalah sebagai berikut:

			AVERAGEIFS(AverageRange; CriteriaRange1; Criteria1; [CriteriaRange2; Criteria2]; ...)
		

Keterangan:

AverageRange

Merupakan sekumpulan data yang akan kita hitung nilai rata-ratanya. Argument ini dapat berupa angka, sel, range, named range, array, atau referensi range data.

CriteriaRange1

Merupakan range data yang akan kita cocokkan dengan kriteria pertama yang diterapkan.

CriteriaRange1

Merupakan syarat pertama yang akan digunakan untuk mengevaluasi argument CriteriaRange1

CriteriaRange2; Criteria2;...

Argumen yang berisi pasangan antara sekumpulan data dan syarat selanjutnya. Argumen ini bersifat opsional (Bisa diisi atau dikosongkan). Maksimal samapai 127 Kriteria

Contoh Rumus AVERAGEIFS Excel

Berikut contoh penerapan fungsi Avergeifs pada rumus excel:

Pada Rumus nomor 1, fungsi AVERAGEIFS digunakan untuk menghitung rata-rata penjualan jenis kelamin "Laki-laki" dengan nilai penjualan diatas 10. Rumus excel yang digunakan:

			=AVERAGEIFS(E2:E11;C2:C11;"Laki-laki";E2:E11;">10")
		

Dengan rumus tersebut hanya data nomor 1,2 dan 8 yang dihiung rata-ratanya. Hasilnya adalah 20.

			(20+20+20)/3
		

Pada contoh rumus AVERAGEIFS nomor 2, fungsi averageifs menghitung rata-rata penjualan untuk jenis kelamin "Perempuan" di wilayah "Barat". Yakni data no 6, 9 dan 10.

			=AVERAGEIFS(E2:E11;C2:C11;"Perempuan";D2:D11;"Barat")
		

Hasilnya adalah 30.

			(40+30+20)/3
		

Pada contoh diatas teks "Laki-laki","Perempuan", "Barat" penulisan formula excelnya bisa juga diganti dengan referensi sel yang berisikan teks tersebut.

Sedangkan contoh nomor 3, rumus AVERAGEIFS digunakan untuk menghitung rata-rata penjualan perempuan diwilyah barat yang nilai penjualannya diatas 20.

			=AVERAGEIFS(E2:E11;C2:C11;"Perempuan";D2:D11;"Barat";E2:E11;">20")
		

Yang memenuhi kriteria tersebut adalah data nomor 6 dan 9 yang menghasilkan rata-rata penjualan 35.

Pada contoh nomor 3 penulisan rumus atau formula excel dari teks kondisi ">20" bisa diarahkan ke referensi sel yang berisi teks tersebut. Jika referensi sel hanya berisi angka 20 tanpa menyertakan operator pembanding lebih dari ">", maka penulisnnya menggunakan operator teks "&". Contoh: ">"&G1. Hal ini juga berlaku untuk operator perbandingan lainnya.

Catatan Dalam Menggunakan Fungsi AVERAGEIFS Excel

Saat menggunakan rumus excel Averageifs ini, ada beberapa hal yang perlu anda perhatikan:

• Jika Argument data AverageRange berisi nilai kosong atau nilai teks, AVERAGEIFS akan menghasilkan nilai kesalahan #DIV0!.
• Sel pada range kriteria yang kosong, oleh AVERAGEIFS akan dianggap bernilai 0.
• Data TRUE dianggap sebagai 1, sedangkan data FALSE dianggap sebagai 0 (nol).
• Pada AVERAGEIFS setiap RangeData dan Kriteria harus berukuran dan berbentuk sama.
• Jika sel-sel dalam Range Kriteria tidak dapat diterjemahkan menjadi angka, AVERAGEIFS menghasilkan nilai kesalahan #DIV0!.
• Jika tidak ada sel yang memenuhi semua syarat atau kriteria, AVERAGEIFS menghasilkan kesalahan #DIV/0!.
• Karakter wildcard berupa tanda tanya (?) dan tanda bintang (*) bisa digunakan dalam menentukan kriteria. Tanda tanya (?) mewakili karakter tunggal apa pun, sedangkan tanda bintang *) mewakili banyak karakter.

Anda menemukan kesulitan?

Silahkan gunakan kolom komentar yang tersedia apabila masih menemui kesulitan saat menghitung rata-rata dengan microsoft Excel.

Beberapa tutorial mengenai rumus rata-rata excel:

• Rumus Average: Rumus menghitung rata-rata di excel
• Rumus Averageif: Cara Menghitung rata-rata dengan sebuah kriteria
• Rumus Averageifs: Cara Menentukan rata-rata dengan banyak kriteria
• Rumus Menghitung rata-rata tanpa mengikutkan angka 0 (Nol) & sel kosong di excel

>> Gabung Telegram Channel <<

Cara Mencari Rata-rata Tanpa Mengikutkan Angka 0 dan Sel Kosong

Cara Mencari Rata-rata Tanpa Mengikutkan Angka 0 dan Sel Kosong

Nadiem    Mei 31, 2020    Comment   

Cara menghitung/mencari rata-rata tanpa mengikutkan angka 0 dan sel kosong pada microsoft excel (Average tanpa menghitung 0)

Menghitung rata-rata nilai tanpa nol - Secara umum untuk menghitung rata-rata di excel adalah dengan menggunakan fungsi Average. Lalu bagaimana jika kita menghendaki mencari rata-rata tanpa mengikutkan angka 0?

Ada beberapa rumus excel yang bisa kita gunakan untuk menghitung atau mencari rata-rata tanpa mengikutkan angka 0 (nol) maupun sel kosong (Blank/Empty Cell) pada excel. Kasus seperti ini lazim di alami oleh para pendidik yang sedang menghitung rata-rata nilai siswa.

Menghitung rata-rata tanpa nol sebenarnya bukanlah sesuatu yang sulit. Sebab excel sudah menyediakan beberapa fungsi statistika khususnya dalam menghitung atau mencari rata-rata. Yang kita butuhkan hanya sedikit kreatifitas dalam menggunakan fungsi-fungsi excel tersebut dalam sebuah rumus excel.

1. Menghitung rata-rata tanpa mengikutkan angka 0 (nol)
2. Menghitung rata-rata tanpa mengikutkan sel kosong (Blank/Empty Cell)
3. Menghitung rata-rata tanpa mengikutkan angka 0 (nol) maupun sel kosong

Untuk lebih jelasnya silahkan pelajari rumus excel berikut.

Mencari Rata-rata Tanpa Mengikutkan Angka 0 (Nol)

Cara menghitung rata-rata pada excel dengan mengabaikan angka 0 (nol) bisa menggunakan rumus AVERAGEIF berikut:

			=AVERAGEIF(RangeData;">0")
		

Dengan rumus diatas excel hanya akan menghitung rata-rata dari range data yang berisi angka diatas 0 (nol). Dengan rumus ini tentunya nilai negatif juga tidak akan diikutkan dalam perhitungan rata-rata nilai. Perhatikan gambar berikut:

Contoh rumus excelnya adalah seperti gambar berikut:

Jika nilai negatif juga ingin diikutkan dalam perhitungan rata-rata maka gunakan rumus:

			=AVERAGEIF(RangeData;"<>0")
		

Perhatikan rumus excel pada gambar berikut.

Mencari Rata-rata Tanpa Mengikutkan Sel Kosong

Penggunaan fungsi AVERAGEIF dalam rumus excel untuk menghitung rata-rata tanpa mengikutkan sel kosong adalah dengan menggunakan berikut:

			=AVERAGEIF(RangeData;"<>")
		

Cara penerapannya ke dalam rumus excel perhatikan gambar dibawah ini.

Dengan menggunakan rumus ini hanya sel kosong saja yang tidak diikutkan dalam perhitungan rata-rata. Adapun sel yang bernilai 0 (Nol) masih diikutkan dalam mencari rata-rata nilai.

Untuk mencari rata-rata tanpa mengikutkan angka 0 dan sel kosong silahkan lanjut ke bagian berikutnya.

Mencari Rata-rata Tanpa Mengikutkan Angka 0 (nol) Maupun Sel Kosong

Untuk menghindari 0 (nol) dan sel kosong dalam perhitungan rata-rata gunakan rumus excel Sebenarnya sama dengan bagian pertama. yakni menggunakan rumus:

			=AVERAGEIF(RangeData;">0")
		

dan atau

			=AVERAGEIF(RangeData;"<>0")
		

Karena dalam kasus ini kita menerapkan dua kriteria maka kita bisa menggunakan alternatif lain, yakni menggunakan fungsi AVERAGEIFS.

			=AVERAGEIFS(RangeData;RangeData;">0";RangeData;"<>")
		

Contoh penerapannya ke dalam rumus excel seperti gambar berikut:

Sebenarnya masih ada banyak rumus-rumus excel lain yang bisa kita gunakan untuk mencari rata-rata tanpa mengikutkan angka 0 maupun sel kosong ini. Hanya saja menurut saya, rumus diatas merupakan rumus yang paling simple dan lebih mudah untuk kita terapkan.

Anda punya kasus lain? Silahkan sampaikan dikolom kementar dibagian bawah.

Beberapa tutorial mengenai rumus rata-rata excel:

• Rumus Average: Rumus menghitung rata-rata di excel
• Rumus Averageif: Cara Menghitung rata-rata dengan sebuah kriteria
• Rumus Averageifs: Cara Menentukan rata-rata dengan banyak kriteria
• Rumus Menghitung rata-rata tanpa mengikutkan angka 0 (Nol) & sel kosong di excel

>> Gabung Telegram Channel <<

Rumus Menghitung Jumlah Data Unik Dengan Fungsi Countif Excel

Rumus Menghitung Jumlah Data Unik Dengan Fungsi Countif Excel

Nadiem    Mei 26, 2020    Comment   

Rumus excel untuk menghitung jumlah data unik/berbeda (Count Unique Values) dengan mengabaikan data duplikat. Baik untuk format data teks maupun angka serta mengabaikan sel kosong (blank cells) menggunakan fungsi Countif excel.

Jika memiliki data yang mengandung data yang sama (double/duplikat). Bagaimanakah rumus excel yang digunakan untuk mengetahui jumlah data uniknya? (count unique value excel).

Menghitung jumlah data unik berarti mencacah banyak data, namun jika pada data tersebut memiliki duplikat hanya dihitung satu kali saja.

Data unik ini bisa saja berupa teks maupun angka, juga campuran dari keduanya.

Untuk tutorial cara mendapatkan list data uniknya bisa anda pelajari pada halaman: Rumus Excel Mendapatkan Data Unik Tanpa Kembar.

Salah satu cara untuk menghitung jumlah data unik dari sebuah range data pada excel adalah dengan menggunakan rumus-rumus excel berikut:

• Menghitung Jumlah Data Yang Berbeda/Unik
• Menghitung Jumlah Data Yang Berbeda/Unik Yang Mengandung Sel Kosong
• Menghitung Jumlah Data Yang Berbeda/Unik Mengabaikan Sel Kosong

Rumus Menghitung Jumlah Data Unik/Berbeda Di Excel

Untuk menghitung jumlah data unik bisa menggunakan rumus gabungan fungsi Sum dan Countif seperti berikut:

			=SUM(1/COUNTIF(RangeData; RangeData))
		

Akhiri dengan Ctrl + Shift + Enter (Array Formula).

Pada contoh diatas jumlah jenis buah pada range A2:A11 dihitung dengan rumus:

			=SUM(1/COUNTIF(A2:A11;A2:A11))
		

Kemudian tekan Ctrl + Shift + Enter , sehingga rumus excel tersebut akan diapit tanda kurung ({...}) seperti yang terlihat di contoh.

Cara kerja rumus excel diatas adalah sebagai berikut:

1. Fungsi Countif akan menghitung jumlah masing-masing jenis buah pada range data: Mangga = 1, Manggis = 3, Rambutan= 1, Sirsak = 1, Manggis = 3, Jeruk = 1, Apel = 2, Manggis= 3, Nanas = 1, Apel = 2
2. Sehingga menghasilkan angka berikut:

			{1;3;1;1;3;1;2;3;1;2}
		

Angka diatas kemudian digunakan untuk membagi angka 1.

			1/{1;3;1;1;3;1;2;3;1;2}
		

Setelah mendapatkan angka tersebut kemudian dijumlahkan dengan fungsi SUM

			=SUM(1/1;1/3;1/1;1/1;1/3;1/1;1/2;1/3;1/1;1/2)
		

Sehingga menghasilkan jumlah unik jenis buah ada 7.

Penjelasan cara kerja rumus diatas sekaligus sebagai penjelasan untuk rumus-rumus excel berikutnya pada tutorial excel kali ini.

Selain menggunakan rumus array gabungan fungsi SUM dan COUNTIF diatas, untuk rumus non Array anda bisa menggunakan gabungan fungsi SUMPRODUCT dan COUNTIF berikut:

			=SUMPRODUCT(1/COUNTIF(RangeData;RangeData))
		

Pada contoh diatas rumus excel yang digunakan untuk menghitung jumlah jenis buah adalah:

			=SUMPRODUCT(1/COUNTIF(A2:A11;A2:A11))
		

Cara kerja rumus diatas kurang lebih sama dengan cara kerja rumus sebelumnya.

Penjelasan lebih detail untuk masing-masing fungsi bisa anda baca pada laman berikut: Rumus SUM Excel, Rumus SUMPRODUCT Excel, Rumus COUNTIF Excel.

Jika data yang kita hitung jumlah nilai uniknya mengandung sel kosong (blank cells), ternyata kedua rumus excel diatas tidak bekerja sesuai harapan. Kedua rumus diatas akan menghasilkan pesan error #DIV/0! seperti pada gambar ini.

Penjelasan tentang jenis-jenis error bisa anda baca pada : Mengenal 7 Jenis Pesan Error pada Rumus Excel.

Rumus Menghitung Jumlah Data Unik Yang Mengandung Cell Kosong

Jika pada range data yang kita hitung nilai uniknya terdapat sel kosong (blank cells). Maka solusinya adalah dengan menambahkan (&"") pada kriteria fungsi Countif, sehingga rumus excelnya menjadi:

			=SUM(1/COUNTIF(RangeData;RangeData&""))
		

Akhiri dengan Ctrl + Shift + Enter .

Untuk rumus non Array menjadi:

			=SUMPRODUCT(1/COUNTIF(RangeData;RangeData&""))
		

Dan hasilnya seperti pada gambar berikut:

Jika anda cermati, ternyata dengan menggunakan rumus excel diatas sel yang kosong (Blank Cells) juga ikut terhitung. Data unik pada contoh diatas seharusnya 6 (Mangga, Manggis, Rambutan, Jeruk, Apel, Nanas), namun hasil rumus diatas 7 sebab sel kosong juga ikut terhitung sehingga plus 1 menjadi 7 Jenis.

Untuk menandai sel yang mengandung data ganda maupun sebaliknya menandai data unik bisa anda baca pada halaman: Cara Menemukan Data Ganda (Duplikat) dan Data Unik Pada Excel

Jika anda bermaksud mengabaikan sel kosong (Blank Cells), maka gunakan rumus excel berikutnya dibawah ini.

Rumus Menghitung Jumlah Data Berbeda & Mengabaikan Cell Kosong

Rumus excel yang digunakan untuk mengetahui jumlah data unik dengan mengabaikan sel kosong (blank cells) adalah sebagai berikut:

			=SUM((RangeData<>"")/COUNTIF(RangeData;RangeData&""))
		

Akhiri dengan Ctrl + Shift + Enter .

Untuk rumus non array bisa menggunakan gabungan Sumproduct dan Countif seperti dibawah ini:

			=SUMPRODUCT((RangeData<>"")/COUNTIF(RangeData;RangeData&""))
		

Contoh penerapannya seperti yang terlihat dalam gambar berikut:

Seperti yang terlihat pada gambar diatas dengan menggunakan rumus array:

			=SUM((A2:A11<>"")/COUNTIF(A2:A11;A2:A11&""))
		

Akhiri dengan Ctrl + Shift + Enter .

atau untuk non Array dengan rumus:

			=SUMPRODUCT((A2:A11<>"")/COUNTIF(A2:A11;A2:A11&""))
		

Kita bisa menghitung jumlah nilai unik dari sebuah range data dan mengabaikan sel yang kosong (sel kosong tidak dihitung).

Untuk data yang cukup besar, menghitung jumlah data unik dengan fungsi COUNTIF diatas sebenarnya masih kurang maksimal. Untuk performance yang lebih baik bisa anda pertimbangkan untuk menggunakan fungsi FREQUENCY.

Panduan lebih lanjut tentang penggunaan fungsi FREQUENCY untuk menghitung jumlah data unik ini bisa anda baca pada halaman berikut: Menghitung Jumlah Data Unik Yang Berbeda Dengan Excel

>> Gabung Telegram Channel <<

Cara Menghitung Jumlah Cell Yang Terisi Teks Tertentu Pada Microsoft Excel

Cara Menghitung Jumlah Cell Yang Terisi Teks Tertentu Pada Microsoft Excel

Nadiem    Mei 15, 2020    Comment   

Rumus excel untuk menghitung jumlah data atau sel yang berisi teks atau mengandung teks tertentu pada microsoft excel.

Pada tutorial rumus excel sebelumnya kita sudah membahas tentang rumus excel untuk menghitung jumlah kata tertentu pada sebuah sel atau range excel. Lalu bagaimana jika yang ingin kita hitung adalah jumlah sel atau banyak datanya?

Secara umum untuk menghitung jumlah sel atau menghitung jumlah data dengan kriteria tertentu, fungsi excel yang bisa kita gunakan adalah fungsi Countif atau fungsi Countifs jika syarat yang akan kita terapkan lebih dari satu.

Secara khusus pada tutorial rumus excel kali ini yang akan kita bahas adalah menghitung sel dengan syarat bahwa sel tersebut berisi teks baik teks secara umum maupun teks tertentu saja.

Penerapan rumus berikut ini akan sangat berguna misalnya untuk menghitung jumlah sel yang berisi kode barang tertentu, baik secara utuh maupun sebagian dari kode-kode barang tersebut.

1. Menghitung Jumlah Data Berisi Teks
2. Menghitung Jumlah Data Yang Mengandung Teks tertentu

Cara Menghitung Cell Yang Berisi Teks di Excel

Untuk menghitung jumlah sel yang tidak kosong kita bisa memanfaatkan fungsi CountA. Tidak kosong disini berarti bahwa isi sel tersebut dapat berupa angka, format tanggal /waktu, teks, formula, nilai error maupun empty teks ("") yang dihasilkan oleh sebuah rumus.

Jika anda bermaksud menghitung sel yang berisi teks saja maka gunakanlah rumus excel berikut ini:

			=COUNTIF(RangeData;"*")
		

Dengan rumus di atas maka:

1. Nilai logika TRUE dan FALSE tidak dihitung sebagai teks.
2. Sel yang bernilai angka/number tidak dihitung sebagai teks meskipun dimasukkan dalam sel yang berformat teks.
3. Blank Sel yang di awali dengan petik tunggal atau apostrophe (') akan dihitung sebagai teks.

Perhatikan contoh berikut:

Rumus excel yang digunakan pada sel E3 di atas adalah:

			=COUNTIF(A2:A8;"*")
		

Dengan rumus di atas angka, nilai error, blank sel, tanggal/waktu serta nilai logika dibaikan sebagai teks.

Selain menggunakan rumus Countif seperti di atas kita juga bisa menghitung jumlah sel yang berisi teks dengan memanfaatkan fungsi Sumproduct pada microsoft excel. Rumus umumnya adalah sebagai berikut:

			=SUMPRODUCT(--ISTEXT(RangeData))
		

Pada rumus ini, Fungsi ISTEXT digunakan untuk mengetahui apakah value sebuah sel pada range data dimaksud merupakan teks atau bukan.

Berikut contoh penerapannya:

			=SUMPRODUCT(--ISTEXT(A2:A8))
		

Strip ganda atau double unary (--) pada rumus tersebut seperti yang sudah dijelaskna sebelumnya digunakan untuk merubah nilai logika TRUE/FALSE menjadi angka 1/0 sehingga bisa di hitung jumlahkan secara aritmatika.

Untuk lebih jelasnya silahkan dibaca pada laman berikut: Double Unary Operator (--) Pada Rumus Array Excel

Dengan rumus-rumus excel di atas, setiap sel yang berisi teks akan dihitung, lalu bagaimana jika kita tidak ingin menghitung semua sel dan hanya ingin menghitung sel yang berisi teks atau sebagian tertentu saja?

Cara Menghitung Cell Yang Berisi Teks Tertentu di Excel

Untuk menghitung jumlah data yang berisi teks tertentu saja salah satu rumus yang bisa digunakan adalah sebagai berikut:

			=COUNTIF(RangeData;"Teks")
		

Pembahasan di atas saya kira sudah cukup dijelaskan pada pemabahasan fungsi excel COUNTIF. untuk itu tidak akan saya jelaskan lebih lanjut.

Kemudian bagaimana jika teks yg dimaksud adalah sebagian teks saja. Artinya sel yang dihitung adalah sel yang mengandung teks tertentu tersebut, bukan hanya sel yang berisi data teks persis seperti kriteria yang dimaksud.

Untuk kasus semacam ini kita bisa memanfaatkan whilcard character pada fungsi Countif seperti ini:

			=COUNTIF(RangeData;"*Teks*")
		

Misalnya seperti pada contoh berikut, rumus yang digunakan untuk menghitung jumlah data/sel yang berisi teks "BJ" rumus excel yang digunakan adalah:

			=COUNTIF(A2:A10;"*BJ*")
		

Untuk teks yang berupa referensi cara penulisannya adalah sebagai berikut:

			=COUNTIF(RangeData;"*"&ReferensiTeks&"*")
		

Contoh penggunaanya seperti dalam gambar berikut:

Jika anda lebih teliti ternyata dengan menggunakan rumus ini, setiap sel yang dihitung ternyata tidak membedakan antara huruf besar dan kecil (non case sensitive), sehingga antara teks "KS" dan "Ks" akan dinggap sama. Jika ingin case sensitive bagaimana solusinya?

Untuk menghitung sel yang berisi teks tertentu dan bersifat case sensitive (Membedakan huruf besar dan kecil) gunakan rumus excel berikut:

			=SUMPRODUCT(--(ISNUMBER(FIND(Teks;RangeData))))
		

Perhatikan contoh berikut:

			=SUMPRODUCT(--(ISNUMBER(FIND(C4;A2:A10))))
		

C4 merupakan referensi sel yang bernilai teks "Ks" sedangkan A2:A10 Merupakan referensi Range yang ingin kita hitung jumlah sel yang terisi teks "Ks".

Fungsi FIND pada rumus ini digunakan untuk mencari posisi atau letak teks secara case sensitive pada sebuah sel. Jika ditemukan maka fungsi Find akan menghasilkan nomor urut teks tersebut dalam bentuk angka.

Fungsi IsNumber sendiri digunakan untuk mengetahui apakah masing-masing hasil dari fungsi Find tadi berupa angka jika iya maka akan menghasilkan nilai logika TRUE dan sebaliknya jika bukan angka akan menghasilkan nilai logika FALSE.

Nilai logika TRUE dan FALSE ini kemudian di konversi ke numeric dengan double unary operator (--) sehingga bisa dihitung jumlahnya oleh fungsi Sumproduct.

Cukup mudah bukan?

Demikian pembahasan kita tentang rumus excel untuk menghitung jumlah sel yang terisi teks tertentu. Jika masih ada kendala silahkan sampaikan pada bagian komentar di bawah.

Silahkan share juga postingan tutorial excel ini, barangkali salah satu teman anda juga membutuhkan.

>> Gabung Telegram Channel <<